Oiler Works
  • Home
    • My resume
    • Free premium
    • Privacy Policy
  • Science & MBA
  • Blog
    • Gaveta de remédios
    • Canadá
    • Computing
    • Presentes

Virtualbox or VMWare conflicting with Hypervisor. No VT-x support.

2/4/2016

0 Comments

 
If you have Microsoft Hypervisor installed, it will take up the cpu VT-x so any other Virtual Machine System will accuse that your system hasn't support to virtualization. You need to disable its launching to release the cpu VT-x support to other VM like Oracle Virtualbox or VMWare.
Source

::
:: Hypervisor VT-x cpu hook flipper
:: Need administrator privileges
::
@cls
@echo off
net session >NUL 2>&1
if %errorlevel% neq 0 (
    echo Administrator privileges required!
    pause
    exit
)
echo:
for /f "tokens=2" %%G in ('bcdedit /enum active ^| find "hypervisorlaunchtype"') do set "$status=%%G"
if /i [%$status%] EQU [off] (
        echo Hypervisor is unavailable [OFF]
        set "$message=Should I bring it up? "
        set "$command=auto"
        
) else if /i [%$status%] EQU [auto] (
        echo Hypervisor is available [ON]
        set "$message=Should I bring it down? "
        set "$command=off"
) else (
        echo:
        echo Something is wrong. Status unknown or Hypervisor not installed.
        echo bcdedit /enum active | find "hypervisorlaunchtype"
        pause
        exit 1
)
choice /c:ny /t 30 /d n /m "%$message%"
echo:
if errorlevel 2 (bcdedit /set hypervisorlaunchtype %$command%
        echo:
        echo You need to restart the OS for changes to take effect.
        pause)
exit 0

0 Comments

Your comment will be posted after it is approved.


Leave a Reply.

    Arquivos

    August 2020
    August 2019
    November 2018
    October 2018
    August 2017
    March 2017
    April 2016
    March 2016
    November 2013
    March 2013
    February 2013
    November 2012
    October 2012

    Categorias

    All
    Bugs
    Linux
    Openwrt
    Windows 8

    RSS Feed

Powered by Create your own unique website with customizable templates.
  • Home
    • My resume
    • Free premium
    • Privacy Policy
  • Science & MBA
  • Blog
    • Gaveta de remédios
    • Canadá
    • Computing
    • Presentes